PC World 2008 February/PCWorld_2008-02_cd.bin/audio-video/reaper/reaper2028-install.exe/Effects/IX/MIDI_Velocifier II

Text File | 2007-12-03 | 5.4 KB | 149 lines

/*
Copyright 2007, Philip S. Considine
All rights reserved.

Redistribution and use in source and binary forms, with or without modification, are permitted
provided that the following conditions are met:

Redistributions of source code must retain the above copyright notice, this list of conditions
and the following disclaimer.

Redistributions in binary form must reproduce the above copyright notice, this list of conditions
and the following disclaimer in the documentation and/or other materials provided with the distribution.

The name of Philip S. Considine may not be used to endorse or promote products derived from this
software without specific prior written permission.

THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY EXPRESS OR
IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND
FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS
BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
(INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*/

////////////////////////////////////////////////////////////////////////////////////////////
desc: MIDI Velocity Effect. Edit for more info.

////////////////////////////////////////////////////////////////////////////////////////////

//Input Channel
slider1:0<0,15,1{1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16}>Input Channel

/*----------- NOTE MIN/MAX You can change these if you want! --------------*/
//Standard Sliders
slider2:0<0,127,1>Note Min
slider3:127<0,127,1>Note Max

//Drop-downs with note names (disabled)
//slider2:0<0,127,1{C0,C#0,D0,D#0,E0,F0,F#0,G0,G#0,A0,A#0,B0,C1,C#1,D1,D#1,E1,F1,F#1,G1,G#1,A1,A#1,B1,C2,C#2,D2,D#2,E2,F2,F#2,G2,G#2,A2,A#2,B2,C3,C#3,D3,D#3,E3,F3,F#3,G3,G#3,A3,A#3,B3,C4,C#4,D4,D#4,E4,F4,F#4,G4,G#4,A4,A#4,B4,C5,C#5,D5,D#5,E5,F5,F#5,G5,G#5,A5,A#5,B5,C6,C#6,D6,D#6,E6,F6,F#6,G6,G#6,A6,A#6,B6,C7,C#7,D7,D#7,E7,F7,F#7,G7,G#7,A7,A#7,B7,C8,C#8,D8,D#8,E8,F8,F#8,G8,G#8,A8,A#8,B8,C9,C#9,D9,D#9,E9,F9,F#9,G9,G#9,A9,A#9,B9,C10,C#10,D10,D#10,E10,F10,F#10,G10}>Note Min
//slider3:127<0,127,1{C0,C#0,D0,D#0,E0,F0,F#0,G0,G#0,A0,A#0,B0,C1,C#1,D1,D#1,E1,F1,F#1,G1,G#1,A1,A#1,B1,C2,C#2,D2,D#2,E2,F2,F#2,G2,G#2,A2,A#2,B2,C3,C#3,D3,D#3,E3,F3,F#3,G3,G#3,A3,A#3,B3,C4,C#4,D4,D#4,E4,F4,F#4,G4,G#4,A4,A#4,B4,C5,C#5,D5,D#5,E5,F5,F#5,G5,G#5,A5,A#5,B5,C6,C#6,D6,D#6,E6,F6,F#6,G6,G#6,A6,A#6,B6,C7,C#7,D7,D#7,E7,F7,F#7,G7,G#7,A7,A#7,B7,C8,C#8,D8,D#8,E8,F8,F#8,G8,G#8,A8,A#8,B8,C9,C#9,D9,D#9,E9,F9,F#9,G9,G#9,A9,A#9,B9,C10,C#10,D10,D#10,E10,F10,F#10,G10}>Note Max
/*-------------------------------------------------------------------------*/

slider4:64<0,127,1>Value
slider5:0<0,100>Variation (%)
slider6:/ix_sequences:none:Sequence File
slider7:1<0,1,1{Off,On}>On/Off

////////////////////////////////////////////////////////////////////////////////////////////
@init

//Set memory offsets
seq = 0;

//MIDI constants
statNoteOn = 9 * 16;

//File change flags
seqFile -1;

////////////////////////////////////////////////////////////////////////////////////////////
@slider

//Catch bad values
slider2 = floor(slider2);
slider3 = floor(slider3);
slider4 = floor(slider4);
slider5 = floor(slider5);

slider2 < 0 ? slider2 = 0; slider2 > 127 ? slider2 = 127;
slider3 < 0 ? slider3 = 0; slider3 > 127 ? slider3 = 127;
slider4 < 0 ? slider4 = 0; slider4 > 127 ? slider4 = 127;
slider5 < 0 ? slider5 = 0; slider5 > 100 ? slider5 = 100;

//Store values
inChannel = slider1;
noteMin = slider2;
noteMax = slider3;
value = slider4;
vRand = slider5 / 100;

slider7 != on ?
(
    on = slider7;
    step = 0;    //Reset step counter
);

//Load sequence
seqFile != slider6|0 ?
(
    seqFile = slider6|0;
    seqSize = 0;
    fileHandle = file_open(slider6);
    fileHandle > 0 && file_text(fileHandle) ?
    (
        while
        (
            file_var(fileHandle,seq[seqSize]);
            file_avail(fileHandle) ? seqSize += 1;
        );
        file_close(fileHandle);
    );
);

////////////////////////////////////////////////////////////////////////////////////////////
@block

while
(
    midirecv(offset,msg1,msg23) ?
    (
        //Check status byte
        status = msg1 & 240; //High four bits is message type (240 == 11110000)
        channel = msg1 & 15; //Low four bits is channel number (15 == 00001111)

        //Is it on our channel
        channel == inChannel && on == 1 ?
        (
            velocity = ((msg23/256) & 127);

            //Is it a note on
            status == statNoteOn && velocity > 0 ?
            (
                t += 1;
                osc = sin(t);    //used to make random values positive or negative

                //get note number and velocity
                note = msg23 & 127;
                velocity = ((msg23/256) & 127);

                //Process if it's within the note range
                note >= noteMin && note <= noteMax ?
                (
                    seq[step] == 1 ? //Check sequence
                    (
                        velocity = floor(value + (rand(value * vRand)*osc));
                        velocity > 127 ? velocity = 127;
                        velocity < 0 ? velocity = 0;
                        msg23 = note |(velocity * 256);
                    );
                    step < (seqSize) ? step += 1 : step = 0; //Update the step counter
                );
            );
        );
        midisend(offset,msg1,msg23);    //Pass if flagged
    );
);